StockFetcher Forums · Filter Exchange · Niko's MAX (Moving Average Crossover) Filter<< 1 ... 3 4 5 6 7 >>Post Follow-up
chetron
2,817 posts
msg #61716
- Ignore chetron		 4/23/2008 6:31:41 AM

CLICKABLE?????


Fetcher[

Show stocks where close is above 7

and average volume(60) is above 70000
and average volume(30) is above 70000
and average volume(17) is above 70000
and average volume(10) is above 70000
and average volume(5) is above 70000

and PPO(5,35) has been increasing for 1 days
and PPO(13,50) has been increasing for 1 days
and CCI has been increasing for 1 days
and Fast Stochastic(13,3) Fast %K has been increasing for 1 days
and MACD histogram(12,26) has been increasing for 1 days
and Momentum has been increasing for 1 days
and Ultimate Oscillator(7,14,28) has been increasing for 1 days
and Bollinger Oscillator(20) has been increasing for 1 days

add column separator
set{OVER, count(TSI(6,3,3) crossed above 0,1) *1}
set{UNDER, count(TSI(6,3,3) crossed below 0,1) * -1}
set{both2, OVER + UNDER}
set{CROSS, 1 - count(both2 equals 0,1)}
add column both2{TSI6}
set{var1, 2 * EMA(9)}
set{var2, cema(ema(9),9)}
set{DEMA, var1 - var2}
set{TEMA, T3(7,1)}
set{xUP, count(DEMA crossed above TEMA,1) *1}
set{xDOWN, count(DEMA crossed below TEMA,1) * -1}
set{both, xUP + xDOWN}
set{xOVER, 1 - count(both equals 0,1)}

add column both{D2/T3}
add column separator

/*close position within a 1-month price range*/
set{hi1mo,high 1 month high}
set{lo1mo,low 1 month low}
set{cllo1mo,close - lo1mo}
set{hilo1mo,hi1mo - lo1mo}
set{diff1,cllo1mo / hilo1mo}
set{%gain1mo,diff1 * 100}

/*close position within a 2-month price range*/
set{hi2mo,high 1 month high 1 month ago}
set{lo2mo,low 1 month low 1 month ago}
set{cllo2mo,close 1 month ago - lo2mo}
set{hilo2mo,hi2mo - lo2mo}
set{diff2,cllo2mo / hilo2mo}
set{%gain2mo,diff2 * 100}

/*close position within a 3-month price range*/
set{hi3mo,high 1 month high 2 month ago}
set{lo3mo,low 1 month low 2 month ago}
set{cllo3mo,close 2 months ago - lo3mo}
set{hilo3mo,hi3mo - lo3mo}
set{diff3,cllo3mo / hilo3mo}
set{%gain3mo,diff3 * 100}

/*EMA calc.*/
set{return1,%gain2mo + %gain3mo}
set{return2,return1 / 2}
set{return3,%gain1mo - return2}
set{return4,return3 * 0.6667}
set{return,return4 + return2}

add column return
draw T3(14,0.5)
draw TEMA on plot price
draw DEMA on plot price
draw TSI(6,3,3)
draw return line at 70
draw return line at 30

and DEMA >= TEMA
and CCI >= 0
and +DI(14) >= -DI(14)
and ADX(14,14) > 18
and ADX(14,14) >= -DI(14)
and Fast Stochastic(5,3) Fast %K > Fast Stochastic(5,3) Slow %D
and Fast Stochastic(13,3) Fast %K > 25
and Stochastic %K(15,5,3) > 25
and close >= T3(14,0.50)
and close > T3(5,0.7)
and close >= MA(40)
and close >= EMA(13)
and close > lower Bollinger Band(20,2.0)
and close > lower Keltner Band(10)

do not draw CROSS
do not draw xOVER
do not draw Momentum
do not draw stochastic(15,5,3) %K
do not draw Fast Stochastic(13,3) %K
do not draw Fast Stochastic(5,3) %K
do not draw ppo(5,35)
do not draw ppo(13,50)
do not draw CCI
do not draw MA(40)
do not draw EMA(13)
do not draw Bollinger Band(20,2.0)
do not draw keltner band(10)
do not draw ultimate oscillator(7,14,28)

]
nikoschopen
2,824 posts
msg #61732
- Ignore nikoschopen		 4/23/2008 12:39:51 PM

Hi bkagarwal,

I'm glad to hear that it's working out for you. The filter is still undergoing further revision (ie. "work in progress"). One of the things that I'm currently looking at (and struggling) is to make the oscillator a little more adaptive to the changing volatility. I wish SF would make VIX available. If anyone has a suggestion, I'm all ears. Thanks.
marine2
963 posts
msg #61735
- Ignore marine2		 4/23/2008 1:01:52 PM

Niko, could you please write this last program into a clickable version for us basic SF users. I and many others would be most appreciative. Thank you.
nikoschopen
2,824 posts
msg #61744
- Ignore nikoschopen		 4/23/2008 4:27:20 PM

marine,

If there's a way to provided a "lite" version without sacrificing the original filter I would most likely have done so already. But you can only take it so far with so many limitation inherent in the basic subscription. Chetron has done a great job of cutting out the fat as much as possible to make it suitable for the basic users, but if you were to add one more line of condition to his modified version you would find ureself running into an insurmountable wall. Hence, I suggest that you upgrade to the advanced subscription.



chetron
2,817 posts
msg #61757
- Ignore chetron		 4/23/2008 7:17:33 PM

bkagarwal / nikos combo for the basics.....
removed excessive do not draw commands
and no 30/70 lines on the return plot

enjoy


Fetcher[



Show stocks where close is above 7

and average volume(60) is above 70000
and average volume(30) is above 70000
and average volume(17) is above 70000
and average volume(10) is above 70000
and average volume(5) is above 70000

and PPO(5,35) has been increasing for 1 days
and PPO(13,50) has been increasing for 1 days
and CCI has been increasing for 1 days
and Fast Stochastic(13,3) Fast %K has been increasing for 1 days
and MACD histogram(12,26) has been increasing for 1 days
and Momentum has been increasing for 1 days
and Ultimate Oscillator(7,14,28) has been increasing for 1 days
and Bollinger Oscillator(20) has been increasing for 1 days

add column separator

set{var92,-1}
set{OVER, count(TSI(6,3,3) crossed above 0,1) *1}
set{UNDER, count(TSI(6,3,3) crossed below 0,1) * var92}
set{both2, OVER + UNDER}
set{CROSS, 1 - count(both2 equals 0,1)}
add column both2{TSI6}
set{var1, 2 * EMA(9)}
set{var2, cema(ema(9),9)}
set{DEMA, var1 - var2}
set{TEMA, T3(7,1)}
set{xUP, count(DEMA crossed above TEMA,1) *1}
set{xDOWN, count(DEMA crossed below TEMA,1) * var92}
set{both, xUP + xDOWN}
set{xOVER, 1 - count(both equals 0,1)}

add column both{D2/T3}
add column separator


/*close position within a 1-month price range*/
set{hi1mo,high 1 month high}
set{lo1mo,low 1 month low}
set{cllo1mo,close - lo1mo}
set{hilo1mo,hi1mo - lo1mo}
set{diff1,cllo1mo / hilo1mo}
set{%gain1mo,diff1 * 100}

/*close position within a 2-month price range*/
set{hi2mo,high 1 month high 1 month ago}
set{lo2mo,low 1 month low 1 month ago}
set{cllo2mo,close 1 month ago - lo2mo}
set{hilo2mo,hi2mo - lo2mo}
set{diff2,cllo2mo / hilo2mo}
set{%gain2mo,diff2 * 100}

/*close position within a 3-month price range*/
set{hi3mo,high 1 month high 2 month ago}
set{lo3mo,low 1 month low 2 month ago}
set{cllo3mo,close 2 months ago - lo3mo}
set{hilo3mo,hi3mo - lo3mo}
set{diff3,cllo3mo / hilo3mo}
set{%gain3mo,diff3 * 100}

/*EMA calc.*/
set{return1,%gain2mo + %gain3mo}
set{return2,return1 / 2}
set{return3,%gain1mo - return2}
set{return4,return3 * 0.6667}
set{return,return4 + return2}

add column return
draw T3(14,0.5)
draw TEMA on plot price
draw DEMA on plot price
draw TSI(6,3,3)
draw return

and DEMA >= TEMA
and CCI >= 0
and +DI(14) >= -DI(14)
and ADX(14,14) > 18
and ADX(14,14) >= -DI(14)
and Fast Stochastic(5,3) Fast %K > Fast Stochastic(5,3) Slow %D
and Fast Stochastic(13,3) Fast %K > 25
and Stochastic %K(15,5,3) > 25
and close >= T3(14,0.50)
and close > T3(5,0.7)
and close >= MA(40)
and close >= EMA(13)
and close > lower Bollinger Band(20,2.0)
and close > lower Keltner Band(10)


do not draw Momentum
do not draw stochastic(15,5,3) %K
do not draw Fast Stochastic(13,3) %K
do not draw Fast Stochastic(5,3) %K
do not draw ppo(5,35)
do not draw ppo(13,50)
do not draw CCI
do not draw MA(40)
do not draw EMA(13)
do not draw Bollinger Band(20,2.0)
do not draw keltner band(10)
do not draw ultimate oscillator(7,14,28)


]
nikoschopen
2,824 posts
msg #61762
- Ignore nikoschopen
modified		 4/24/2008 3:40:53 AM

Thanks Chet, but I think I finally figured it out. It seems to look fine for now but let me know if you find a bug or two.

Okie, here's the "lite" version for y'all basic subscribers.

MAX Down

Fetcher[
set{OVER,count(TSI(6,3,3) crossed above 0,1) * 1}
set{UNDER,count(TSI(6,3,3) crossed below 0,1) * -1}
set{both, OVER + UNDER}
set{both2,OVER - UNDER}
both2 above 0

set{var1, 2 * EMA(9)}
set{var2, cema(ema(9),9)}
set{DEMA, var1 - var2}
set{TEMA, T3(7,1)}
set{UP, count(DEMA crossed above TEMA,1)}
set{DOWN, count(DEMA crossed below TEMA,1) * -1}
set{either, UP + DOWN}
set{either2, UP - DOWN}
either2 above 0

set{%gain1mo, Slow Stochastic(22) Fast %K}
set{%gain2mo, %gain1mo 1 month ago}
set{%gain3mo, %gain1mo 2 months ago}
set{return1,%gain2mo + %gain3mo}
set{return2,return1 / 2}
set{return3,%gain1mo - return2}
set{return4,return3 * 0.6667}
set{return,return4 + return2}

add column both{TSI6}
add column either{D2/T3}
add column return 1 day ago{return(-1)}
add column return

draw T3(14,0.5)
draw TEMA on plot price
draw DEMA on plot price
draw TSI(6,3,3)
draw return line at 70
draw return line at 30
do not draw both2
do not draw either2

return 1 day ago crossed above 70 and return below 60
]


MAX Up

Fetcher[
set{OVER,count(TSI(6,3,3) crossed above 0,1) * 1}
set{UNDER,count(TSI(6,3,3) crossed below 0,1) * -1}
set{both, OVER + UNDER}
set{both2,OVER - UNDER}
both2 above 0

set{var1, 2 * EMA(9)}
set{var2, cema(ema(9),9)}
set{DEMA, var1 - var2}
set{TEMA, T3(7,1)}
set{UP, count(DEMA crossed above TEMA,1)}
set{DOWN, count(DEMA crossed below TEMA,1) * -1}
set{either, UP + DOWN}
set{either2, UP - DOWN}
either2 above 0

set{%gain1mo, Slow Stochastic(22) Fast %K}
set{%gain2mo, %gain1mo 1 month ago}
set{%gain3mo, %gain1mo 2 months ago}
set{return1,%gain2mo + %gain3mo}
set{return2,return1 / 2}
set{return3,%gain1mo - return2}
set{return4,return3 * 0.6667}
set{return,return4 + return2}

add column both{TSI6}
add column either{D2/T3}
add column return 1 day ago{return(-1)}
add column return

draw T3(14,0.5)
draw TEMA on plot price
draw DEMA on plot price
draw TSI(6,3,3)
draw return line at 70
draw return line at 30
do not draw both2
do not draw either2

return 1 day ago crossed below 30 and return above 40
]
chetron
2,817 posts
msg #61764
- Ignore chetron		 4/24/2008 6:56:48 AM

very nice niko. a thing of beauty.



money123
19 posts
msg #62464
- Ignore money123		 5/10/2008 4:22:14 PM

nice filter when should we use this before during or after the market opens thanks
nikoschopen
2,824 posts
msg #62465
- Ignore nikoschopen		 5/10/2008 5:01:03 PM

Quote from money123:

nice filter when should we use this before during or after the market opens thanks
First, I should point out that I left out price and volume criteria from the "lite" version of this filter. I strongly recommend that you avoid stocks that trade under 10 and/or volume less than 300,000. Having said that, I would run this filter just prior to the close and closely monitor where the stock would open the following morning. Here's a rough guideline that can be used for both Max UP & Max Down:

Max UP

  • If the stock opens moderately higher than the previous day's close (that is, if it's not a significant gap), then wait until it reverses back down to or near its previous day's close before entering the trade.
  • If the stock opens lower than the previous day's close, enter the trade only when it crosses and closes above the previous day's close. This is akin to "Wait for Green" that you hear so often here.
Max DOWN

  • If the stock opens moderately lower than the previous day's close (that is, if it's not a significant gap), then wait until it reverses back up to or near its previous day's close before entering the trade.
  • If the stock opens higher than the previous day's close, enter the trade only when it crosses and closes below the previous day's close. This is akin to "Wait for Red" that you hear so often here.
nikoschopen
2,824 posts
msg #62527
- Ignore nikoschopen
modified		 5/12/2008 5:52:31 PM

The idea behind this filter was derived in part from WSG's filter.

Unlike the previous filter, this filter will combine both long and short setups.

Columns: There are three customized columns

Bull(1) / Bear(-1): This is pretty self-explanatory. If bullish, a value of 1 will be shown; if bearish, -1.

WFR(-1): This will show the value of WFR 1 day ago.

WFR*: Today's WFR

* WFR is a combination of Williams %R, (Inverse) Fisher Transform, and the RSI.

How to interpret the filter

The basic premise of this filter is to find stocks that have either crossed above 95 yesterday but have since fallen and closed under 95 (bearish) or crossed below -95 yesterday but have since risen and closed above 95 (bullish). When the stock is bullish, you will see the value of 1 shown in the first column, followed by numbers greater than 95 and less than 95 in the second and third columns, respectively. When the stock is bearish, you will see the value of -1 shown in the first column, followed by numbers greater than -95 and less than -95 in the second and third columns, respectively.

For ADVANCED subscribers

Fetcher[
set{Wrsi, RSI(2) - Williams %R(7)}
set{WFR, Wrsi * Inverse Fisher Transform(5,9)}

set{Over, count(WFR crossed above 95,1)}
set{Under, count(WFR crossed below -95,1) * -1}
set{Center, count(WFR between 85 and -85,1)}
set{Both, Over + Under}
set{None, 1 - count(Both equals 0,1)}
set{None2, Both * -1}
None 1 day ago above 0 and Center equals 1

add column None2 1 day ago{Bull(1) / Bear(-1)}
add column WFR 1 day ago{WFR(-1)}
add column WFR
draw WFR line at 95
draw WFR line at -95
do not draw Cross
do not draw None
do not draw Center

price above 20
avgvol(17) above 300000
]


For BASIC subscribers

Fetcher[
set{Wrsi, RSI(2) - Williams %R(7)}
set{WFR, Wrsi * Inverse Fisher Transform(5,9)}

set{Over, count(WFR crossed above 95,1)}
set{Under, count(WFR crossed below -95,1) * -1}
set{Center, count(WFR between 85 and -85,1)}
set{Both, Over + Under}
set{None,Over - Under}
set{None2, Both * -1}
None 1 day ago above 0 and Center equals 1

add column None2 1 day ago{Bull(1) / Bear(-1)}
add column WFR 1 day ago{WFR(-1)}
add column WFR
draw WFR line at 95
draw WFR line at -95
do not draw Cross
do not draw None
do not draw Center

price above 20
avgvol(17) above 300000
]
StockFetcher Forums · Filter Exchange · Niko's MAX (Moving Average Crossover) Filter<< 1 ... 3 4 5 6 7 >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.