StockFetcher Forums · Filter Exchange · Hull MA50 + momentim<< >>Post Follow-up
graftonian
1,089 posts
msg #147214
- Ignore graftonian		 4/5/2019 1:26:47 PM


Fetcher[
optionable
Average Volume(30) > 5000000

/*HULL MA50 */
set{slow1, cwma(close, 25)}
set{slow2, 2 * slow1}
set{slow3, cwma(close, 50)}
set{valslow, slow2 - slow3}
set{H50, cwma(valslow, 7)}
draw H50 on plot price
/**/
set{trigger1, count(close crossed above H50, 1)}
set{trigger2, count(slope of H50 > 0.1, 1)}
set{trigger3, count(StochRSI(5,5) > .8, 1)}
set{trigger4, trigger1 * trigger2}
set{trigger, trigger4 * trigger3}
trigger equals 1
draw trigger

draw StochRSI(5,5)
draw StochRSI(5,5) line at .8
add column 2 day slope of H50
sort on column 5 descending
]
Cheese
1,374 posts
msg #147233
- Ignore Cheese
modified		 4/6/2019 12:08:59 PM

Thank you for sharing your filters and ideas over the years.

The following may be a value added quick win.

Fetcher[


/* FOR ILLUSTRATIVE PURPOSE ONLY */

symlist(DIS,CRM) /* in March 2019 DIS and CRM got some false signals from the 4-trigger H50 */

/* HOW GRAFTONIAN's GUPPY WIDTHS COULD HELP AVOID false signals from the 4-TRIGGER Hull50 in March 2019 */


CHART-TIME 3 MONTHS
optionable
Average Volume(30) > 5000000

/*HULL MA50 */
set{slow1, cwma(close, 25)}
set{slow2, 2 * slow1}
set{slow3, cwma(close, 50)}
set{valslow, slow2 - slow3}
set{H50, cwma(valslow, 7)}
draw H50 on plot price
/**/
set{trigger1, count(close crossed above H50, 1)}
set{trigger2, count(slope of H50 > 0.1, 1)}
set{trigger3, count(StochRSI(5,5) > .8, 1)}
set{trigger4, trigger1 * trigger2}
set{trigger, trigger4 * trigger3}
/* trigger equals 1 */
draw trigger


draw StochRSI(5,5) line at .8
add column 2 day slope of H50
sort on column 5 descending


/* ******************************************************************** */

/*
https://www.stockfetcher.com/forums/General-Discussion/Interesting-Book-to-read-Daryl-Guppy-Trend-trading/134862/-1/134908
graftonian 3/13/2017 8:46:04 PM
*/

/* Guppy MMA */
market is not OTCBB
Average Volume(30) > 1000000
/* close between .50 and 10 */

/*short term emas*/
draw EMA(3)
draw EMA(5)
draw EMA(7)
draw EMA(9)
draw EMA(11)
draw EMA(13)
/*add a point for every pair "stacked right" */
set{SS35, count(EMA(3) > EMA(5),1)}
set{SS57, count(EMA(5) > EMA(7), 1)}
set{SS79, count(EMA(7) > EMA(9), 1)}
set{SS911, count(EMA(9) > EMA(11), 1)}
set{SS1113, count(EMA(11) > EMA(13), 1)}

set{ss1, SS35 + SS57}'
set{ss2, ss1 + SS79}
set{ss3, ss2 + SS911}
set{short_term_score, ss3 + SS1113}

/*long term emas*/
draw EMA(70)
draw EMA(60)
draw EMA(50)
draw EMA(40)
draw EMA(35)
draw EMA(30)

set{LS6070, count(EMA(60) > EMA(70), 1)}
set{LS5060, count(EMA(50) > EMA(60), 1)}
set{LS4050, count(EMA(40) > EMA(50), 1)}
set{LS3540, count(EMA(35) > EMA(40), 1)}
set{LS3035, count(EMA(30) > EMA(35), 1)}
set{LS1, LS6070 + LS5060}
set{LS2, LS1 + LS4050}
set{LS3, LS2 + LS3540}
set{long_term_score, LS3 + LS3035}

/*
draw long_term_score
draw short_term_score
*/
set{comp_score, long_term_score + short_term_score}

add column separator
add column short_term_score
add column long_term_score
add column comp_score
add column separator

/*trader/investor separation */
set{tisep, ema(13) - ema(30)}
set{tisep2, tisep / ema(30)}
set{tiseppct, tisep2 * 100}
add column tiseppct{TR_INV_SEP}

/* trader group width */
set{tgw, ema(3) - ema(13)}
set{tgw2, tgw / ema(13)}
set{trad_grp_width, tgw2 * 100}
add column trad_grp_width

/* investor group width */
set{igw, ema(30) - ema(70)}
set{igw2, igw / ema(70)}
set{inv_grp_width, igw2 * 100}
add column inv_grp_width
draw inv_grp_width
draw trad_grp_width on plot inv_grp_width
draw inv_grp_width line at 0

/* investor annualized slope percent */
set{iasp, slope of ema(50)}
set{iasp2, iasp / ema(50)}
set{iasp3, iasp2 * 25000}
add column iasp3

/* FILTER */
/* TO FIND BOTH GROUPS COMPRESSED */
/* trad_grp_width between -1 and 1 */
/* inv_grp_width between -1 and 1 */

do not draw comp_score
]
graftonian
1,089 posts
msg #147245
- Ignore graftonian		 4/8/2019 8:20:49 AM

Cheese,
Thanks for the analysis. Perhaps adding some code to flag Investor and Trader group width > 0 and increasing.
Graf
StockFetcher Forums · Filter Exchange · Hull MA50 + momentim<< >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.