shillllihs
6,101 posts
msg #105594
- Ignore shillllihs |
3/22/2012 1:34:04 AM
/*KEVIN'S TRADE THE WEEKLY OPEN GAP DOWN STRATEGY*/
/*FIRST, SET KEY VARIABLES - LAST WEEK'S CLOSE AND THIS WEEK'S OPEN*/
set{horizontal1, weekly close 1 week ago}
set{open1, weekly open}
/*SECOND, DETERMINE IF A GAP DOWN OCCURS, AND IF IT WAS THEN FILLED*/
set{gapdown, count(open1 below horizontal1,1)}
set{stats, count(weekly high above horizontal1, 1)}
set{gapfill, gapdown * stats}
/*THIRD, COUNT THE FREQUENCY OF GAPS DOWN THAT WERE FILLED OVER THE LAST 100 WEEKS*/
set{gapdown100, count(gapdown above 0.5,100)}
set{gapfill100, count(gapfill above 0.5,100)}
set{pct_gapfill, gapfill100 / gapdown100}
/*FINALLY, DETERMINE THE POTENTIAL GAIN FROM THIS WEEK'S GAP DOWN*/
set{gapsize, horizontal1 - open1}
set{gain2, gapsize / open1}
set{gain, gain2 * 100}
/*NOW ADD COLUMNS WITH KEY DATA AND SORT THEM FROM HIGHEST PERCENT GAP FILLED TO LOWEST*/
add column pct_gapfill {percent gap filled}
add column gapdown100
add column gapfill100
add column horizontal1 {last week's close}
add column open1 {weekly open}
add column gain {gain(%)}
add column ATR(50)
sort on column 5 descending
/*SET SCREENING CRITERIA FOR USE AT MONDAY'S OPEN. SINCE BIG GAPS DOWN ARE LESS LIKELY
TO BE FILLED, SCREEN OUT ANY GAPS DOWN THAT OPEN BELOW LAST WEEK'S LOW*/
weekly open below weekly close 1 week ago
weekly open above weekly low 1 week ago
/*ADDED CHECK - THE GAP TO BE FILLED SHOULD BE LESS THAN THE ATR(50). THIS WILL ALSO HELP TO SCREEN OUT BIG GAPS DOWN THAT ARE UNLIKELY TO BE FILLED THIS WEEK*/
gapsize below ATR(50)
/*SET A MINIMUM FREQUENCY FOR GAPS DOWN - THE HIGHER THIS IS, THE STRONGER THE STATISTICAL RELEVANCE - I CHOSE 30 HERE BUT YOU CAN SET IT TO ANYTHING YOU WANT (HIGHER WILL GIVE FEWER
HITS). I ALSO WANT THE RETURN TO BE AT LEAST 2%*/
gapdown100 above 30
gain above 2
/*STANDARD LIQUIDITY REQUIREMENTS*/
close above 1
average volume(30) above 100000
show only etf
chart-display is weekly
draw gapfill
draw gapdown
|
Kevin_in_GA
4,599 posts
msg #105888
- Ignore Kevin_in_GA |
4/11/2012 6:24:57 PM
Limiting this to only ETFs will not give you a lot of trades, and will probably only pull up the double and triple leveraged ones.
I think there is more profit to be had looking at a larger set of instruments - I would look for liquidity of at least $2,000,000 per day so your order does not represent more than a few percent of the dollar volume. There is also no reason to limit this to only Monday ... One could just as easily use a "open below close 1 day ago" approach here and trade it daily to get more trades per week.
Kevin
|